#! /bin/csh
# getmucla - C Shell script to download data from MUCLA can under test
#	     and extract the data
#
set oasis = /oasis
set can = mucla
set tncaddr = "MUCLA"

cd $oasis/test/raw
set noclobber
set noglob
set datafilebase = `date +%Y%j`
set failmail = "headley@mbari.org"

set i = 0
set datafile = $can.$datafilebase.00
while ( -e $datafile )
	@ i++
	set datafile = $can.$datafilebase.`printf "%02d" $i`
end

$oasis/bin/getoasis -a "$tncaddr" >& $datafile
set rtnsts = $status

if ( $rtnsts ) then
	/bin/mailx -s "Failed OASIS Download" $failmail << !
Download failure of file $datafile 
Return code was $rtnsts
	0 = Success
	1 = Argument error (bad command line arguments)
	2 = Couldn't acquire TNC port (there's probably a hung download)
	3 = Couldn't connect to OASIS (it's not listening)
	4 = Download error (something broke after it connected)
	5 = Abort error (somebody killed the download)
`date`
!
endif

set errorfile = $oasis/test/mucla/error/$datafile

if ( (-e $datafile) && !(-z $datafile) ) then
	$oasis/bin/extract -y1 -c $oasis/cfg/mucla.cfg $datafile >& $errorfile
endif

if ( -z $errorfile ) \
	rm -f $errorfile
