#! /bin/csh
# deployMooring - C Shell script to move data for mooring deployment
#

if ($#argv < 2 ) then
echo "Usage $0 <mooring> <archive dir> [<instrument>...]"
echo "mooring:    mooring directory name (m1)"
echo "archivedir: directory name (may2000)"
echo "instrument: new instrument directory names (fluor metsys)"
exit
endif

set mooring = $1
set archive = $2

set oasis = /oasis
set mooringdir = $oasis/$mooring
set archdir = $oasis/$archive
set tardir = $oasis/raw/tar
set rawdir = $oasis/raw
set cfgdir = $oasis/cfg
set srcdir = $oasis/src
set bindir = $oasis/bin
set headerdir = $oasis/cfg/$mooring
set erasedir = $oasis/raw/erase
set PROCESS = $oasis/bin/process

echo "\nThis is a potentially destructive script. Do not use it unless you know exactly what it does."
echo "Make sure that downloads are OFF, and that no download\n is currently in progess.\n"
echo "You are about to perform deployment file maintenance for $mooring."
echo "Old data will be stored in $archdir."

echo "Press ^C now to exit or any other key to proceed"

set foo = ($<)

# create archive directory
echo "\n\nCreating Directories..."
mkdir $archdir
mkdir $archdir/raw

echo "Processing Current Data..."
$PROCESS $mooring

echo "Archiving Current Data..."
# TAR file cleanup...
cd $tardir

# unzip the tar archive...
gunzip $mooring.tar.gz
cd $rawdir
cp $mooring.* $erasedir

# put any remaining raw files in the archive...
tar -rvf $tardir/$mooring.tar $mooring.*
rm $mooring.*

# update the tar directory file
tar -tvf $tardir/$mooring.tar >& $tardir/$mooring.dir

# zip up tar file and move to archive
cd $tardir
gzip $mooring.tar

echo "Moving Archive..."
mv $mooring.* $archdir/raw
mv $mooringdir $archdir

echo "Moving System Files..."
# archive bin, src, cfg directories
cp -r $bindir $archdir
cp -r $srcdir $archdir
cp -r $cfgdir $archdir

echo "Creating New Archive..."
# create new tar files
date > newarch
tar -cvf $mooring.tar newarch
tar -tvf $mooring.tar > $mooring.dir
gzip $mooring.tar
rm -f newarch

echo "Removing Headers..."
rm $headerdir/*.hdr

echo "Creating New Directories..."
# create new mooring directories

cd $oasis
echo "$mooring..."
mkdir $mooring
cd $mooring
echo "error..."
mkdir error
echo "data..."
mkdir data
echo "oasis..."
mkdir oasis

if ($#argv >= 2) then
@ i = 3
while ($#argv >= $i )
echo "$argv[$i]..."
mkdir $argv[$i]
@ i++
end
endif

echo "Done.\n Copies of the last raw data are in $erasedir."
echo "Remember to:"
echo "  - Update Header Files ($cfgdir/$mooring/)"
echo "  - Replace $bindir/$mooring.cfg"
echo "  - Modify TNC callsign in  $bindir/get$mooring"
echo "  - Reset oasis.rcd $mooring records"
echo "  - Restore Downloads"