#! /bin/csh
# getm2 - C Shell script to download data from M2 
#	     and extract the data with logging
#
# Copyright (C) 2001 MBARI
# Author: Kent Headley
# MBARI provides this documentation and code "as is", with no warranty,
# express or implied, of its quality or consistency. It is provided without
# support and without obligation on the part of the Monterey Bay Aquarium
# Research Institute to assist in its use, correction, modification, or
# enhancement. This information should not be published or distributed to
# third parties without specific written permission from MBARI.

set oasis = /oasis
set can = m2
set tnc = 2001M2
set tncaddr = "$tnc v mbari-2"
set logfile = "dlinfo.log"

cd $oasis/raw
set noclobber
set noglob
set datafilebase = `date +%Y%j`
set failmail = "headley@mbari.org,zorba@mbari.org,w3ab@mbari.org,eric@mbari.org"

set i = 0
set datafile = $can.$datafilebase.00
while ( -e $datafile )
	@ i++
	set datafile = $can.$datafilebase.`printf "%02d" $i`
end

set starttime = `date +"%x %H:%M:%S"`

$oasis/bin/getoasis -a "$tncaddr" -p "tnc2" -c $can >& $datafile
set rtnsts = $status

set endtime = `date +"%x %H:%M:%S"`

set filesize = `ls -l $datafile|sed -f $oasis/bin/fs.sed`
unset noclobber
echo "$datafile,$starttime,$endtime,$filesize,$rtnsts" >> $logfile
set noclobber

echo -n $rtnsts "  " >> filelist
ls -l $datafile >> filelist

if ( $rtnsts ) then
	/bin/mailx -s "Failed OASIS Download" $failmail << !
Download failure of file $datafile
Return code was $rtnsts
	0 = Success
	1 = Argument error (bad command line arguments)
	2 = Couldn't acquire TNC port (hung download or port in use)
	3 = Couldn't connect to OASIS (it's not listening)
	4 = Download error (something broke after it connected)
	5 = Abort error (somebody killed the download)
`date`  *** message from $tnc ***
!
endif

set errorfile = $oasis/$can/error/$datafile

if ( (-e $datafile) && !(-z $datafile) ) then
	$oasis/bin/extract -r -n -y1 $datafile >& $errorfile
endif

if ( -z $errorfile ) \
	rm -f $errorfile