# Copyright (C) 2001 MBARI
# Author: Kent Headley
# MBARI provides this documentation and code "as is", with no warranty,
# express or implied, of its quality or consistency. It is provided without
# support and without obligation on the part of the Monterey Bay Aquarium
# Research Institute to assist in its use, correction, modification, or
# enhancement. This information should not be published or distributed to
# third parties without specific written permission from MBARI.

# getMooring - C Shell script to download data from OASIS Controller
#	     and extract the data
#
# Must use full DOS path instead of symlink to /oasis since tclsh80 converts
# UNIX ('/') paths to DOS ('\') paths

set TRUE = 1
set FALSE = 0

#
# Directories
#
set OASIS = /oasis/test
set CFG = $OASIS/cfg
set RAW = $OASIS/raw
set BIN = $OASIS/bin
set CAN_MASTER=m46044
set CAN_SLAVE=$FALSE

if ( $CAN_SLAVE == $FALSE) then
set CAN = $CAN_MASTER
else
set CAN = $CAN_MASTER-$CAN_SLAVE
endif

set ERROR_DIR = $OASIS/$CAN/error

#
# General 
#
set FILEBASE = `date +%Y%j`
# Missing Records File
set RCDFILE = $RAW/oasis.rcd
# Download Logs (old & new)
set DLLOG = "dlinfo"
set OLDLOG = "dlinfo.log"
set TRUE = 1
set FALSE = 0

set noclobber
set noglob

#
# extract Configuration
#
set EXTRACT = $BIN/extract2
set CFGFILE = $CFG/$CAN.cfg
set EXTRACT_OPTS = "-B -r -f $RCDFILE -y 1 -c $CFGFILE"
set DATAFILE = $CAN.$FILEBASE.00
set i = 0
while ( -e $RAW/$DATAFILE )
	@ i++
	set DATAFILE = $CAN.$FILEBASE.`printf "%02d" $i`
end
set ERRORFILE = $ERROR_DIR/$DATAFILE

#
# TNC Configuration
#
set TNC_CALL = "2012M46044"
set TNC_ADDR = "$TNC_CALL"
set TNC_TYPE = n

#the deployed vipr address TBD
##### TURN OFF AFTER TESTING !!!!! 
####set TNC_PORT = 134.89.45.28:10000
####set TNC_PORT = 134.89.45.28:20000
set TNC_PORT = 134.89.45.28:30000

#lab qualtech DS400D Port1 - in the BirdCage
#set TNC_PORT = 134.89.12.116:5001

#richs office oasis3 test-jig
#set TNC_PORT = 134.89.10.88:5001

#
# getoasis Configuration
#
if ( $CAN_SLAVE == $FALSE) then
set DOWNLOAD = $BIN/vipr4slaves
set DOWNLOAD_OPTS = " -p $TNC_PORT -c $CAN_MASTER -r $RCDFILE -n 30"
else
set DOWNLOAD = $BIN/vipr4slaves
set DOWNLOAD_OPTS = " -p $TNC_PORT -c $CAN_MASTER -s $CAN_SLAVE -r $RCDFILE -n 30"
endif

#
# Fail Mail
#
#set FAILMAIL = "rich@mbari.org"
#set FAILMAIL = "rich@mbari.org,dfrench@mbari.org,kemi@mbari.org"
set ENABLE_FAILMAIL = $FALSE
set MAIL_SUBJECT = "Failed OASIS Download"
# oasis (Tsunami/HPUX)
set MAIL = "/bin/mailx -s "
set MAIL_MSG = "** message from OASIS $TNC_CALL **"


#############################################
# Should not need to modify below this line #
#############################################

cd $RAW

# Record start of download
set starttime = `date +"%x %H:%M:%S"`
set starttime_es = `perl -e 'print time, "\n"'`

# Download the data and record error status
echo "$DOWNLOAD $DOWNLOAD_OPTS  >& $DATAFILE"
$DOWNLOAD $DOWNLOAD_OPTS  >& $DATAFILE
set rtnsts = $status

# Record the end of download
set endtime = `date +"%x %H:%M:%S"`
set endtime_es = `perl -e 'print time, "\n"'`

# Get the raw data filesize
set filesize = `ls -l $DATAFILE | sed -f $BIN/fs.sed`

# Log download statistics and submit to SSDS - IDs are unique for mooring deployment
#deviceId is ssds virtual device for download process
#parentId is the ssds id for the toroid

# sn/1 2009,2011,2013 etc
#set deviceId = 1698
#set parentId = 1414

#sn/2 2010,2012,2014 etc
#set deviceId = 1768
#set parentId = 1305

unset noclobber
echo "$DATAFILE,$starttime,$endtime,$filesize,$rtnsts" >> $DLLOG.$FILEBASE
#####/oasis/bin/ssdsSubmit.pl $deviceId $parentId "$starttime_es,$endtime_es,$filesize,$rtnsts"
echo "$DATAFILE,$starttime,$endtime,$filesize,$rtnsts" >> $OLDLOG
set noclobber

#
# Send failmail
#
if ($ENABLE_FAILMAIL == $TRUE) then
if ( $rtnsts ) then
	$MAIL "$MAIL_SUBJECT" $FAILMAIL << !
Download failure of file $DATAFILE 
Return code was $rtnsts
	0 = Success
	1 = Argument error (bad command line arguments)
	2 = Couldn't acquire TNC port (hung download or someone's using port)
	3 = Couldn't connect to OASIS (it's not listening)
	4 = Download error (something broke after it connected)
	5 = Abort error (somebody killed the download)
`date` $MAIL_MSG
!
endif
endif

# Extract data
if ( (-e $DATAFILE) && !(-z $DATAFILE) ) then
	echo "$EXTRACT $EXTRACT_OPTS $DATAFILE >& $ERRORFILE"
	$EXTRACT $EXTRACT_OPTS $DATAFILE >& $ERRORFILE


#######rip tstring for ssds processing
######echo "$BIN/riptstring2 -b -y 1 -c $CFGFILE $RAW/$DATAFILE"
######$BIN/riptstring2 -b -y 1 -c $CFGFILE $RAW/$DATAFILE

endif




# Remove error file if no errors
if ( -z $ERRORFILE ) then
	rm -f $ERRORFILE
endif

#######set SEND_SSDS = $TRUE
set SEND_SSDS = $FALSE

# Send the data to SSDS
# Added 20 Jan 2005 Bob Herlien
#
if ( $SEND_SSDS == $TRUE ) then
  echo "remsh elvis -l ssdsadmin dev/DPforSSDS/oasis/bin/oasisToSSDS -b -c $CFGFILE $RAW/$DATAFILE"
  remsh elvis -l ssdsadmin dev/DPforSSDS/oasis/bin/oasisToSSDS -b -c $CFGFILE -persistFile /mbari/ssdsdata/mooring/$CAN.persist $RAW/$DATAFILE &

#  process an oasis binary file which is intended to be a modified tstring-only datafile
  remsh elvis -l ssdsadmin dev/DPforSSDS/oasis/bin/oasisToSSDS -b -c $CFGFILE -persistFile /mbari/ssdsdata/mooring/$CAN.tso.persist $RAW/$DATAFILE.tso
  mv $RAW/$DATAFILE.tso $RAW/erase
endif