#! /bin/csh
# getmoor - C Shell script to download data from OASIS moorings at M1 and M2
#	    and extract the data
#
set oasis = /usr/local/oasis
set can = `echo "m1a m1b m2"`
set mooring = `echo "m1 m1 m2"`
set tncaddr = `echo "mbari-3 mbari-4 mbari-5"`
set repeater = mbari-2

cd $oasis/raw
set noclobber
set noglob
set datafilebase = `date +%y%j`
set failmail = hebo@mbari.org

foreach loop (1 2 3)
	set i = 0
	set datafile = $can[$loop].$datafilebase.00
	while ( -e $datafile )
		@ i++
		set datafile = $can[$loop].$datafilebase.`printf "%02d" $i`
	end

	set errorfile = $oasis/$mooring[$loop]/error/$datafile

	$oasis/bin/getoasis -a "$tncaddr[$loop] v $repeater" >& $datafile
	set rtnsts = $status

	if ( $rtnsts ) then
	mailx -s "Failed OASIS Download" $failmail << !
		Download failure of file $datafile 
		Return code was $rtnsts
		`date`
!
endif

	if ( (-e $datafile) && !(-z $datafile) ) then
		$oasis/bin/extract $datafile >& $errorfile
	endif

	if ( -z $errorfile ) \
		rm -f $errorfile
end