#! /bin/tcsh

# deployMoor - C Shell script that wraps doDeploySetup, which
# does file maintance for mooring deployments.
# This script issues a warning, prompts for OK before proceeding, and 
# redirects stdout and stderr to a log file. doDeploySetup does the actual
# file maintenance, w/o any user interaction.
# Since it doesn't do any user interaction, doDeploySetup can be 
# used standalone, or be called from another script.

if ($#argv < 2 ) then
echo "Usage $0 <mooring> <archive dir> [<instrument>...]"
echo "mooring:    mooring directory name (m1)"
echo "archivedir: directory name (may2000)"
echo "instrument: new instrument directory names (fluor metsys)"
exit
endif

echo "\nThis is a potentially destructive script. Do not use it unless you know exactly what it does."
echo "Make sure that downloads are OFF, and that no download\nis currently in progess.\n"
echo "You are about to perform deployment file maintenance for $1."
echo "Old data will be stored in $2."

# wait for key press to continue
echo "Press ^C now to exit or any other key to proceed"
set foo = ($<)

set filedate = `date +%Y%m%d`_`date +%H%M`
set logdir=`pwd`
set logfile = deployMoor-$filedate.log

if (! -e $logfile ) then
echo "creating logfile: $logdir/$logfile"
 touch $logdir/$logfile
 echo "## deployMoor Log File" >> $logdir/$logfile
 echo "## created: "`date` >> $logdir/$logfile
endif

if ( ! -e "$logfile" ) then
 echo "warning: $logfile could not be created"
endif
#2>&1 | tee -a $logdir/$logfile
doDeploySetup $argv |& tee -a $logdir/$logfile

echo "Output written to $logdir/$logfile"