# Copyright (C) 2001 MBARI
# Author: Kent Headley
# MBARI provides this documentation and code "as is", with no warranty,
# express or implied, of its quality or consistency. It is provided without
# support and without obligation on the part of the Monterey Bay Aquarium
# Research Institute to assist in its use, correction, modification, or
# enhancement. This information should not be published or distributed to
# third parties without specific written permission from MBARI.

# getMooring - C Shell script to download data from OASIS Controller
#	     and extract the data
#
# Must use full DOS path instead of symlink to /oasis since tclsh80 converts
# UNIX ('/') paths to DOS ('\') paths
#
# Modified 10/20/2005 for the 2005M1 deployment EBN
#
# Directories
#
set OASIS = /oasis
set CFG = $OASIS/cfg
set RAW = $OASIS/raw
set BIN = $OASIS/bin
set CAN = m1 
set ERROR_DIR = $OASIS/$CAN/error

#
# General 
#
set FILEBASE = `date +%Y%j`
# Missing Records File
set RCDFILE = $RAW/oasis.rcd
# Download Logs (old & new)
set DLLOG = "dlinfo"
set OLDLOG = "dlinfo.log"
set TRUE = 1
set FALSE = 0

set noclobber
set noglob

#
# extract Configuration
#
set EXTRACT = $BIN/extract
set CFGFILE = $CFG/$CAN.cfg
set EXTRACT_OPTS = "-r -f $RCDFILE -y 1 -c $CFGFILE"
set DATAFILE = $CAN.$FILEBASE.00
set i = 0
while ( -e $RAW/$DATAFILE )
	@ i++
	set DATAFILE = $CAN.$FILEBASE.`printf "%02d" $i`
end
set ERRORFILE = $ERROR_DIR/$DATAFILE

#
# TNC Configuration
#
set TNC_CALL = "2005M1"
set TNC_ADDR = "$TNC_CALL"
# p: PACCOMM k: Kenwood t: Teledesign n: None (requires wakeup hardware)
set TNC_TYPE = t 
set TNC_PORT = tnc
set RADIO_ADDRESS = "+TSFA01001"
set PING_PERIOD = 1

#
# getoasis Configuration
#
set DOWNLOAD = $BIN/getoasis
set DOWNLOAD_OPTS = "-b 9600  -T $TNC_TYPE -R "$RADIO_ADDRESS" -p $TNC_PORT -P $PING_PERIOD -a "$TNC_ADDR" -c $CAN -r $RCDFILE"

#
# Fail Mail
#
set FAILMAIL = "w3ab@mbari.org,eric@mbari.org,zorba@mbari.org"
set ENABLE_FAILMAIL = $TRUE
set MAIL_SUBJECT = "Failed OASIS Download"
# oasis (Tsunami/HPUX)
set MAIL = "/bin/mailx -s"
set MAIL_MSG = "** message from OASIS $TNC_CALL **"

#
# Send Data to SSDS
# Added 20 Jan 2005, Bob Herlien

set SEND_SSDS = $FALSE


#############################################
# Should not need to modify below this line #
#############################################

cd $RAW

# Record start of download
set starttime = `date +"%x %H:%M:%S"`

# Download the data and record error status
$DOWNLOAD $DOWNLOAD_OPTS  >& $DATAFILE
set rtnsts = $status

# Record the end of download
set endtime = `date +"%x %H:%M:%S"`

# Get the raw data filesize
set filesize = `ls -l $DATAFILE | sed -f $BIN/fs.sed`

# Log download statistics
unset noclobber
echo "$DATAFILE,$starttime,$endtime,$filesize,$rtnsts" >> $DLLOG.$FILEBASE
echo "$DATAFILE,$starttime,$endtime,$filesize,$rtnsts" >> $OLDLOG
set noclobber

#
# Send failmail
#
if ($ENABLE_FAILMAIL == $TRUE) then
if ( ($rtnsts) != 0 ) then
	/bin/mailx -s "Failed OASIS Download" $FAILMAIL << !
Download failure of file $DATAFILE 
Return code was $rtnsts
	0 = Success
	1 = Argument error (bad command line arguments)
	2 = Couldn't acquire TNC port (hung download or someone's using port)
	3 = Couldn't connect to OASIS (it's not listening)
	4 = Download error (something broke after it connected)
	5 = Abort error (somebody killed the download)
`date` $MAIL_MSG
!
endif
endif

# Extract data
if ( (-e $DATAFILE) && !(-z $DATAFILE) ) then
	$EXTRACT $EXTRACT_OPTS $DATAFILE >& $ERRORFILE
endif

# Remove error file if no errors
if ( -z $ERRORFILE ) then
	rm -f $ERRORFILE
endif


# Send the data to SSDS
# Added 20 Jan 2005 Bob Herlien
#
if ( $SEND_SSDS == $TRUE ) then
    remsh mammoth -l ssdsadmin dev/DPforSSDS/oasis/bin/oasisToSSDS -c $CFGFILE $RAW/$DATAFILE &
endif